El emisor de eventos

Un emisor de eventos, también denominado origen de eventos (event source o event sender), es un objeto capacitado para generar y lanzar eventos al sistema, que puedan ser recuperados por otros objetos preparados para realizar su tratamiento. Para que un objeto pueda desencadenar eventos, en su clase debemos realizar dos tareas: 

• • Declarar el propio evento usando la palabra clave Event, especificando si es necesario una lista de parámetros que acompañan al evento. 
• Lanzar el evento mediante la palabra clave RaiseEvent, seguida del nombre del evento a provocar. Si hemos declarado el evento con parámetros, deberemos añadir los valores para cada uno de los parámetros en el mismo orden en el que los hemos declarado. 

Situándonos pues ante el problema planteado por la clase Empleado en un apartado anterior, la solución que proponemos consistirá en generar desde la clase Empleado un evento cuando se produzca un fallo en la validación del sueldo. De esta manera, el código cliente que lo necesite, responderá al evento, y el que no lo precise, hará caso omiso del evento lanzado. 

En primer lugar, declaramos en la zona de declaraciones de la clase el evento LimiteSueldo, que irá acompañado de un parámetro que nos informará del importe erróneo que se intentaba asignar a la propiedad. 

A continuación, en la propiedad Sueldo, cuando detectemos que el sueldo sobrepasa el valor permitido, en lugar de lanzar allí el mensaje a la consola, generaremos el evento LimiteSueldo, que podrá ser recuperado por el código cliente que haga uso de la clase, actuando como necesite en cada ocasión. Observe el lector, que al mismo tiempo que lanzamos el evento, le pasamos el importe del sueldo que se intentaba asignar. Veamos el Código fuente 331.

Public Class Empleado

' declaramos el evento

Public Event LimiteSueldo(ByVal ldbImporte As Double)

Private msNombre As String

Private mdbSueldo As Double

Public Property Nombre() As String

Get

Return msNombre

End Get

Set(ByVal Value As String)

msNombre = Value

End Set

End Property

Public Property Sueldo() As Double

Get

Return mdbSueldo

End Get

Set(ByVal Value As Double)

' si el valor que intentamos asignar

' al sueldo supera el permitido...

If Value > 1000 Then

' ...lanzamos el evento, y le pasamos

' como parámetro informativo el valor

' incorrecto que intentábamos asignar

RaiseEvent LimiteSueldo(Value)

Else

mdbSueldo = Value

End If

End Set

End Property

End Class

Código fuente 331

Con estas modificaciones sobre la clase Empleado, ya tenemos listo nuestro emisor de eventos. Queda ahora por completar la parte que captura los eventos lanzados por el emisor.