Enlace tardío - II

Por ejemplo, si aparte de nuestra conocida clase Empleado, escribimos otra nueva llamada Proveedor, con algunos aspectos similares, como las propiedades Nombre, Apellidos, el método MostrarDatos( ), etc., podremos utilizar una misma variable para manipular cada uno de los objetos que instanciemos de estas clases; evidentemente, tendremos que asignar el objeto pertinente a la variable antes de poder manejarlo. 

Vamos incluso a crear otra clase más, llamada Horario, con un método que devuelva la hora actual del sistema, y ejecutaremos dicho método asignando un objeto de esta clase a la misma variable utilizada para manejar los objetos Empleado y Proveedor. Veamos todo en el Código fuente 241.

Module General

Sub Main()

' tipificamos como Object,

' por lo que obtendremos enlace tardío

Dim loVariosObj As Object

' instanciamos un objeto de Empleado

loVariosObj = New Empleado()

loVariosObj.Nombre = "Juan"

loVariosObj.Apellidos = "Rollo"

loVariosObj.MostrarDatos()

' instanciamos un objeto de Proveedor

loVariosObj = New Proveedor()

loVariosObj.Nombre = "Alicia"

loVariosObj.Apellidos = "Cañaveral"

loVariosObj.MostrarDatos()

' instanciamos un objeto de Horario

loVariosObj = New Horario()

loVariosObj.HoraActual()

End Sub

End Module

Public Class Empleado

Private msNombre As String

Private msApellidos As String

Public Property Nombre() As String

Get

Return msNombre

End Get

Set(ByVal Value As String)

msNombre = Value

End Set

End Property

Public Property Apellidos() As String

Get

Return msApellidos

End Get

Set(ByVal Value As String)

msApellidos = Value

End Set

End Property

Public Sub MostrarDatos()

Console.WriteLine("El empleado seleccionado es: {0} {1}", _

msNombre, msApellidos)

Console.ReadLine()

End Sub

End Class

Public Class Proveedor

Private msNombre As String

Private msApellidos As String

Public Property Nombre() As String

Get

Return msNombre

End Get

Set(ByVal Value As String)

msNombre = Value

End Set

End Property

Public Property Apellidos() As String

Get

Return msApellidos

End Get

Set(ByVal Value As String)

msApellidos = Value

End Set

End Property

Public Sub MostrarDatos()

Console.WriteLine("El proveedor actual es: {0} {1}", _

msNombre, msApellidos)

Console.ReadLine()

End Sub

End Class

Public Class Horario

Public Sub HoraActual()

Console.WriteLine("Hora del sistema: {0}", Format(Now(), "HH:mm"))

Console.ReadLine()

End Sub

End Class

Código fuente 241

De cara a próximos apartados referentes a la herencia, tengamos en cuenta la siguiente regla respecto a los tipos de enlace. 

El enlace temprano se basa en el tipo de la referencia o clase establecida al declarar la variable, mientras que el enlace tardío se basa en el tipo del propio objeto asignado a la variable, sin tener en cuenta la clase con que haya sido declarada la variable.